fm[ρt_,θt_]:=(Sqrt[((1-ρt^2)/(1+ρt^2-2ρt Cos[θt]))]);
fp[ρt_,θt_]:=(Sqrt[((1-ρt^2)/(1+ρt^2+2ρt Cos[θt]))]);
pcp[x_,qt_,ft_]:=(1/(Sqrt[π]))ft (E^(-ft^2(((qt-x))^2)));

Manipulate[
qt=q0 Cos[t]+p0 Sin[t];
pt=p0 Cos[t]-q0 Sin[t];
fmt=fm[ρ0,θ0+2t];
fpt=fp[ρ0,θ0+2t];
prob[x_]=pcp[x,qt,fmt];
prmom[y_]=pcp[y,pt,fpt];
wig[q_,p_]=(1/(Sqrt[π]))(E^(-(((p-pt)^2)/(fmt^2))-(((q-qt)^2)/(fpt^2))+((4ρ0(q-qt) (p-pt) Sin[θ0+2t])/(1-ρ0^2))));

GraphicsGrid[{{DensityPlot[wig[x,p],{x,-5,5},{p,-5,5},PlotRange->All,ColorFunction->"ThermometerColors",PlotPoints->40,Axes->True,AxesLabel->{p,q},PlotLabel->"Phase space Wigner distribution",PerformanceGoal->"Speed"]},
{Plot[prob[x],{x,-5,5},PlotRange->{0,1.5},Axes->None,Frame->True,FrameLabel->q,PlotLabel->"Position probability density",PerformanceGoal->"Speed"]},
{Plot[prmom[y],{y,-5,5},PlotRange->{0,1.5},Axes->None,Frame->True,FrameLabel->p,PlotLabel->"Momentum probability density",PerformanceGoal->"Speed"]}}],

Style["Translation",12,Bold],{{q0,0.5,"q-space"},-1,1,0.1},{{p0,0.5,"p-space"},-1,1,0.1},
Dynamic[Show[Graphics[{Circle[{0,0},Sqrt[p0^2+q0^2]],{PointSize[Large],Red,Point[{q0 Cos[t]+p0 Sin[t],p0 Cos[t]-q0 Sin[t]}]}}],ImageSize->100,PlotLabel->Style["(q(t),p(t))"]]],Delimiter,Style["Squeezing",12,Bold],{{ρ0,0.5,"amount"},0,0.7,0.1},{{θ0,Pi/4,"angle"},0,2Pi,Pi/16},
Dynamic[Show[Graphics[{Circle[],{PointSize[Large],Blue,Point[{ρ0 Cos[θ0+2t],ρ0 Sin[θ0+2t]}]}}],ImageSize->100,PlotLabel->Style["ζ(t)"]]],
Delimiter,{{t,0,"Time"},0,2Pi,0.01},TrackedSymbols:>{p0,q0,ρ0,θ0,t},ControlPlacement->Left,SaveDefinitions->True]